home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD004b.dsk / KENO.PROG.bas < prev    next >
BASIC Source File  |  2003-06-12  |  15KB  |  307 lines
  1. 10  DIM SR(16,16),PI(100),P(30),S(20),TP$(16,5),PO%(16,5),HP$(16),B(10):SS =  -16336: REM      SOUND
  2. 20  GOSUB 6000: REM    TITLE PAGE
  3. 30  GOSUB 300: REM    SEED RANDOM NUMBER
  4. 35  GOSUB 7000: REM     INSTRUCTIONS
  5. 40  GOSUB 5000: REM  INTRO
  6. 50  GOSUB 1000: REM    GET PAY-OFF DATA 1
  7. 60  GOSUB 1200: REM   GET PAY-OFF DATA 2
  8. 70  GOSUB 1300: REM    PAY-OFF DATA 3
  9. 75  GOSUB 1350: REM   GET HOUSE % 
  10. 80  GOSUB 1500: REM   DISPLAY BETTING OPTIONS
  11. 100  GOSUB 1700: REM   INPUT BETS
  12. 120  GOSUB 2000: REM   GET #'S
  13. 150  GOSUB 3100: REM   FIND WINNINGS
  14. 170  IF QT = 1  THEN  GOSUB 9000: REM   QUIT SEQUENCE
  15. 190  GOTO 80
  16. 200  END 
  17. 299  REM  <CTRL-J><CTRL-J><CTRL-J><CTRL-J>
  18. 300  HOME :A$ = "": POKE  -16368,0: REM   SEED RANDOM NUMBER
  19. 301  VTAB 23: PRINT "PRESS ANY KEY TO SEED."
  20. 302  VTAB 20: PRINT "SEED GAME ==>"
  21. 303  FOR I = 1 TO 9: VTAB 20: HTAB 16 +I: PRINT  CHR$(95);: NEXT 
  22. 305 I = 1
  23. 307 Z = 0
  24. 310  VTAB 20: HTAB 16 +I: PRINT Z;
  25. 315 KE =  PEEK( -16384): IF KE >128  THEN 350
  26. 320 Z = Z +1: IF Z >9  THEN Z = 0
  27. 325  GOTO 310
  28. 350  POKE  -16368,0:A$ = A$ + STR$(Z):I = I +1: IF I <10  THEN 307
  29. 355 RN =  VAL(A$)
  30. 360  FOR I = 1 TO 6:B(I) = (RN/255) - INT(RN/255)
  31. 365 B(I) =  INT(B(I) *255)
  32. 370 RN = RN - INT(RN/255)
  33. 375  NEXT I
  34. 380  POKE 201,B(1): POKE 202,B(2): POKE 203,B(3): POKE 204,B(4): POKE 205,B(5): POKE 206,B(6)
  35. 399  RETURN : REM <CTRL-J><CTRL-J><CTRL-J>
  36. 1000  REM  GET WINNINGS DATA
  37. 1090 I = 1:X = 1
  38. 1100  READ SR(I,X)
  39. 1110 X = X +1: IF X >I  THEN I = I +1:X = 1: IF I >15  THEN  RETURN 
  40. 1120  GOTO 1100
  41. 1199  REM  <CTRL-J><CTRL-J><CTRL-J>
  42. 1200  REM  PAY-OFF DATA 2
  43. 1210  FOR I = 1 TO 15
  44. 1220  FOR X = 1 TO 4
  45. 1230  READ TP$(I,X): REM   INPUT TICKET PRICES
  46. 1240  NEXT X
  47. 1250  NEXT I
  48. 1260  RETURN 
  49. 1299  REM  <CTRL-J><CTRL-J><CTRL-J><CTRL-J>
  50. 1300  REM  PAY-OFF DATA 3
  51. 1305  FOR I = 1 TO 15
  52. 1310  FOR X = 1 TO 4
  53. 1320  READ PO%(I,X)
  54. 1330  NEXT X
  55. 1340  NEXT I
  56. 1345  RETURN : REM <CTRL-J> <CTRL-J>
  57. 1350  REM  GET HOUSE PERCENTAGE
  58. 1360  FOR I = 1 TO 15
  59. 1365  READ HP$(I)
  60. 1370  NEXT 
  61. 1380  RETURN : REM <CTRL-J><CTRL-J><CTRL-J>
  62. 1400  REM  SPECIAL BETS
  63. 1410  FOR ZZ = 7 TO 23: VTAB ZZ: HTAB 1: CALL  -868: NEXT ZZ
  64. 1420  VTAB 7: INVERSE : PRINT "SPECIAL": PRINT : NORMAL 
  65. 1430  PRINT " 1..CONSECUTIVE <1> (1,2,3,4.......)"
  66. 1432  PRINT " 2..ALTERNATING <2> (1,3,5,7.......)"
  67. 1434  PRINT " 3..ALTERNATING <3> (1,4,7,10......)"
  68. 1436  PRINT " 4..ALTERNATING <4> (1,5,9,13......)"
  69. 1438  PRINT " 5..ALTERNATING <5> (1,6,11,16.....)"
  70. 1440  PRINT " 6..ALTERNATING <6> (1,7,13,19.....)"
  71. 1442  PRINT " 7..ALTERNATING <7> (1,8,15,22.....)"
  72. 1444  PRINT " 8..ALTERNATING <8> (1,9,17,25.....)"
  73. 1445  PRINT " 9..ALTERNATING <9> (1,10,19,28....)"
  74. 1446  PRINT "10..ALTERNATING <10> (1,11,21,31...)"
  75. 1450 : PRINT : PRINT "WHICH (1-10) (0 TO EXIT) ";: INPUT A$
  76. 1455 SP =  VAL(A$): IF SP = 0  THEN 1810
  77. 1460  PRINT : PRINT "INPUT BEGINING VALUE ";: INPUT A$:BG =  VAL(A$)
  78. 1465  IF BG = 0  THEN 1460
  79. 1475  FOR X = I TO S:S(X) = BG:BG = BG +SP: IF BG >80  THEN BG = 1
  80. 1478  NEXT X
  81. 1480  GOTO 1900
  82. 1490  REM  <CTRL-J><CTRL-J><CTRL-J>
  83. 1500  REM  DISPLAY BETTING OPTIONS
  84. 1510  HOME : HTAB 11: INVERSE : PRINT " PLACE YOUR BETS ": NORMAL 
  85. 1520  PRINT 
  86. 1525  PRINT "CATAGORY==>     1     2      3      4": PRINT 
  87. 1527  FOR I = 1 TO 15: ON I GOSUB 1530,1540,1550,1555,1557,1560,1570,1580,1590,1600,1610,1620,1630,1640: NEXT I
  88. 1528  RETURN 
  89. 1530  VTAB 5: PRINT "  1-SPOT ==> $1.00  $2.00  $3.00": RETURN 
  90. 1540  VTAB 6: PRINT "  2-SPOT ==> $ .25  $ .50  $1.00": RETURN 
  91. 1550  VTAB 7: PRINT "  3-SPOT ==> $ .25  $ .50  $1.00": RETURN 
  92. 1555  VTAB 8: PRINT "  4-SPOT ==> $ .25  $ .50  $1.00": RETURN 
  93. 1557  VTAB 9: PRINT "  5-SPOT ==> $ .50  $1.00  $5.00": RETURN 
  94. 1560  VTAB 10: PRINT "  6-SPOT ==> $ .50  $1.00  $5.00": RETURN 
  95. 1570  VTAB 11: PRINT "  8-SPOT ==> $ .50  $1.00  $7.00": RETURN 
  96. 1580  VTAB 12: PRINT "  9-SPOT ==> $ .50  $1.00  $2.00  $4.00": RETURN 
  97. 1590  VTAB 13: PRINT " 10-SPOT ==> $ .25  $ .50  $1.00  $2.50": RETURN 
  98. 1600  VTAB 14: PRINT " 11-SPOT ==> $ .55  $1.10  $2.75": RETURN 
  99. 1610  VTAB 15: PRINT " 12-SPOT ==> $ .40  $ .80  $2.40": RETURN 
  100. 1620  VTAB 16: PRINT " 13-SPOT ==> $ .95  $2.85  $5.70": RETURN 
  101. 1630  VTAB 17: PRINT " 14-SPOT ==> $1.25  $5.00 $10.00": RETURN 
  102. 1640  VTAB 18: PRINT " 15-SPOT ==> $1.50  $7.50 $15.00": RETURN 
  103. 1650  RETURN 
  104. 1660  REM  <CTRL-J><CTRL-J><CTRL-J>
  105. 1700  REM  INPUT BET
  106. 1710  VTAB 20: PRINT "INPUT RATE (# OF SPOTS)  "
  107. 1720  VTAB 21: INPUT "(1-15)  ";A$
  108. 1725  IF A$ = ""  THEN 1732: REM  SAME AS LAST TIME
  109. 1730 S =  VAL(A$): IF S <1  OR S >15  OR S = 7  THEN  GOTO 1720
  110. 1732  INVERSE 
  111. 1735  ON S GOSUB 1530,1540,1550,1555,1557,1560,0,1570,1580,1590,1600,1610,1620,1630,1640
  112. 1737  NORMAL 
  113. 1740  VTAB 20: HTAB 1: CALL  -868: VTAB 21: CALL  -868: VTAB 20: HTAB 1: PRINT "INPUT TICKET AMMOUNT CATAGORY (1-4) ";: GET A$
  114. 1745  IF A$ =  CHR$(13)  THEN 1800: REM  SAME AS LAST TIME
  115. 1750 BT =  VAL(A$): IF BT <1  OR BT >4  THEN 1740
  116. 1760 TP =  VAL(TP$(S,BT)): IF TP = 0  THEN 1740
  117. 1770  REM  TP=TICKET PRICE  A$=TICKET PRICE STRING
  118. 1780  REM  <CTRL-J><CTRL-J><CTRL-J>
  119. 1800  REM  INPUT BETS
  120. 1810  HOME : INVERSE : HTAB 13: PRINT "INPUT NUMBERS": PRINT : PRINT S;"-SPOT BET";: HTAB (32): PRINT "(S)PECIAL";: NORMAL 
  121. 1820  PRINT "TICKET PRICE= ";:A$ = TP$(S,BT): PRINT "$";A$;: HTAB 28: PRINT "HOUSE : ";HP$(S);"%";
  122. 1850  FOR I = 1 TO 40: PRINT "-";: NEXT 
  123. 1860 I = 1
  124. 1870  VTAB I +6: HTAB 1: PRINT "BET NUMBER ";: IF I <10  THEN  PRINT " ";
  125. 1875  PRINT I;" ==>";: INPUT " ";B$
  126. 1877  IF B$ = "S"  THEN  GOTO 1400
  127. 1878  IF B$ = ""  THEN  VTAB I +6: HTAB 20: INVERSE : PRINT S(I): NORMAL : GOTO 1880
  128. 1879 S(I) =  VAL(B$)
  129. 1880  IF S(I) <1  OR S(I) >80  THEN 1870
  130. 1884 XX = I -1
  131. 1885  IF S(I) = S(XX)  THEN 1870
  132. 1886 XX = XX -1: IF XX >0  THEN 1885: REM  CHECK FOR DUPLICATE BET
  133. 1890 I = I +1: IF I >S  THEN 1900
  134. 1895  GOTO 1870
  135. 1900  PRINT : INVERSE : PRINT "PRESS ANY KEY TO RUN BETS.             ";: GET A$: NORMAL : PRINT 
  136. 1999  RETURN : REM  <CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J>
  137. 2000  REM  SHOW NUMBERS
  138. 2010  HOME : FOR I = 1 TO 20
  139. 2020  IF I <10  THEN  PRINT " ";
  140. 2030  PRINT I;"  ";I +20;"  ";I +40;"  ";I +60
  141. 2040  NEXT I
  142. 2045  VTAB 1: HTAB 18: PRINT "NUMBERS BET ON";
  143. 2050  REM  DISPLAY NUMBERS BET ON
  144. 2060  FOR I = 1 TO S: VTAB I +2: HTAB 30: IF S(I) <10  THEN  PRINT " ";
  145. 2070  PRINT S(I): NEXT 
  146. 2080  REM  <CTRL-J><CTRL-J><CTRL-J>
  147. 2100  REM  CLEAR FLAGS AND COMPUTE NUMBERS
  148. 2120  FOR I = 1 TO 80:PI(I) = 0: NEXT 
  149. 2130 I = 0
  150. 2140 X =  INT( RND(1) *80) +1
  151. 2150  IF PI(X) = 1  THEN 2140
  152. 2160 PI(X) = 1:I = I +1:P(I) = X
  153. 2170  IF I >20  THEN 2200
  154. 2180  GOTO 2140
  155. 2200  FOR I = 1 TO 20
  156. 2210  IF P(I) < = 20  THEN 2300
  157. 2220  IF P(I) < = 40  THEN 2350
  158. 2230  IF P(I) < = 60  THEN 2400
  159. 2240  VTAB P(I) -60: HTAB 13: INVERSE : PRINT P(I);: NORMAL : NEXT : GOTO 3000
  160. 2300  VTAB P(I): HTAB 1: INVERSE : IF P(I) <10  THEN  PRINT " ";
  161. 2310  PRINT P(I);: NORMAL : NEXT : GOTO 3000
  162. 2350  VTAB P(I) -20: HTAB 5: INVERSE : PRINT P(I);: NORMAL : NEXT : GOTO 3000
  163. 2400  VTAB P(I) -40: HTAB 9: INVERSE : PRINT P(I);: NORMAL : NEXT : GOTO 3000
  164. 3000  RETURN 
  165. 3001  REM  <CTRL-J><CTRL-J><CTRL-J><CTRL-J>
  166. 3100  REM  FIND WINNINGS
  167. 3105 W = 0
  168. 3110  FOR I = 1 TO S
  169. 3120  FOR X = 1 TO 20
  170. 3130  IF P(X) = S(I)  THEN W = W +1
  171. 3140  NEXT X: NEXT I
  172. 3200  VTAB S +4: HTAB 18: PRINT "WINNING SPOTS  ";W
  173. 3202 WN = SR(S,W)
  174. 3203 WN = WN *PO%(S,BT)
  175. 3205 WT = WT +WN -TP:WT =  INT(WT *100 +.5)/100
  176. 3210  VTAB S +5: HTAB 18: PRINT "WINNINGS  $";WN: VTAB S +6: HTAB 18: PRINT "TOTAL     $";WT
  177. 3220  VTAB S +7: HTAB 18: PRINT "PERCENT    "; INT(100 *((WT/BS) +.00001));"%"
  178. 3280  POKE  -16368,0: REM  CLEAR KEYBOARD STROBE
  179. 3290  VTAB 23: HTAB 1: INVERSE : PRINT "PRESS 'Q' TO QUIT, ANY OTHER KEY TO PLAY";: NORMAL : VTAB 22: HTAB 1: GET A$: PRINT 
  180. 3295  IF A$ = "Q"  THEN QT = 1
  181. 3300  RETURN 
  182. 3310  REM  <CTRL-J><CTRL-J><CTRL-J>
  183. 5000  REM  TITLE PAGE
  184. 5015  HOME : PRINT "WELCOME TO KENO...": PRINT : PRINT "RECALL OLD GAME (Y/N) ";: GET A$: PRINT : IF A$ = "Y"  THEN 5100
  185. 5020  HOME : PRINT "WELCOME TO KENO..": PRINT : PRINT : INPUT "PLEASE INPUT STAKE  $";BS
  186. 5030 WT = BS: REM  WINNINGS TOTALS =BEGINNING STAKE
  187. 5050  RETURN : REM  <CTRL-J><CTRL-J><CTRL-J>
  188. 5100  REM  GET OLD STATS
  189. 5105  GOSUB 9200: REM  GET FILE #
  190. 5110 D$ =  CHR$(4)
  191. 5120  PRINT D$;"OPEN KENO DATA FILE ";A$
  192. 5130  PRINT D$;"READ KENO DATA FILE ";A$
  193. 5140  INPUT WT
  194. 5150  INPUT BS
  195. 5160  PRINT D$;"CLOSE KENO DATA FILE ";A$
  196. 5170  PRINT : PRINT "OLD BEGINING STAKE = $";BS: PRINT : PRINT "OLD WINNINGS TOTAL = $";WT
  197. 5180  PRINT : PRINT "PERCENT               "; INT(100 *((WT/BS) +.00001));"%"
  198. 5190  FOR I = 1 TO 1000: NEXT : REM  PAUSE
  199. 5200  RETURN : REM  <CTRL-J><CTRL-J><CTRL-J>
  200. 6000  HOME : REM   FLASHY DISPLAY
  201. 6010  INVERSE : HTAB 14: PRINT "CASINO KENO": VTAB 23: PRINT "      PRESS ANY KEY TO BEGIN PLAY       ";: NORMAL 
  202. 6020  FOR I = 1 TO 15: ON I GOSUB 1530,1540,1550,1555,1557,1560,1570,1580,1590,1600,1610,1620,1630,1640: NEXT I
  203. 6030  FOR I = 1 TO 15: INVERSE 
  204. 6040  ON I GOSUB 1530,1540,1550,1555,1557,1560,1570,1580,1590,1600,1610,1620,1630,1640
  205. 6045 SU =  PEEK(SS) - PEEK(SS) + PEEK(SS)
  206. 6047 KE =  PEEK( -16384): IF KE >127  THEN  NORMAL : POKE  -16368,0: RETURN 
  207. 6050  FOR PA = 1 TO 100: NEXT 
  208. 6060  NORMAL : ON I GOSUB 1530,1540,1550,1555,1557,1560,1570,1580,1590,1600,1610,1620,1630,1640: NEXT I
  209. 6100  GOTO 6030
  210. 6110  REM  <CTRL-J><CTRL-J><CTRL-J>
  211. 7000  REM     INSTRUCTIONS
  212. 7005  HOME : VTAB 10: PRINT "INSTRUCTIONS (Y/N)? ";: GET A$: IF A$ = "N"  THEN  RETURN 
  213. 7010  HOME : HTAB 11: INVERSE : PRINT "KENO INSTRUCTIONS": NORMAL : PRINT 
  214. 7020  PRINT "KENO IS A CASINO GAME OF CHANCE..       THE RULES ARE AS FOLLOWS:": PRINT 
  215. 7030  PRINT "WITHIN THE RANGE OF 1-80, 20 NUMBERS AREPICKED AT RANDOM.  YOU BET ON A CHOSEN  QUANTITY OF NUMBERS AT A CHOSEN TICKET  PRICE.  IF YOUR NUMBERS COME UP, YOU    ARE PAID OFF ACCORDING TO THE PRICE OF"
  216. 7040  PRINT "YOUR TICKET, THE NUMBER OF SPOTS        (NUMBERS) YOU BET ON AND THE NUMBER OF  CORRECT GUESSES."
  217. 7050  PRINT : PRINT 
  218. 7060  PRINT "NOTE: THE MORE CORRECT NUMBERS AND THE  HIGHER THE TICKET PRICE, THE HIGHER THE PAY-OFF."
  219. 7070  VTAB 24: INVERSE : PRINT "    PRESS ANY KEY                    ";: GET A$: PRINT 
  220. 7080  HOME : HTAB 11: INVERSE : PRINT "KENO INSTRUCTIONS": NORMAL : PRINT 
  221. 7090  PRINT "AFTER YOU HAVE MADE YOUR FIRST SET OF   BETS, YOU MAY REPEAT THE LAST BET MADE  BY JUST PRESSING RETURN WHEN PROMPTED   FOR A NEW BET.": PRINT 
  222. 7100  PRINT "(S)PECIAL BET:  ENTER 'S' INSTEAD OF A  NUMBER TO ENABLE THE AUTOMATIC BETTING  SEQUENCE.  HERE YOU MAY SPECIFY AN      INCREMENT AND A STARTING VALUE FOR YOUR SELECTED NUMBERS."
  223. 7110  PRINT : PRINT "NOTE:  YOU MAY INVOKE THE SPECIAL BET   FEATURE AT ANY POINT IN THE NUMBER      IDENTIFICATION SEQUENCE."
  224. 7115  VTAB 24: INVERSE : PRINT "   PRESS ANY KEY                    ";: GET A$: PRINT 
  225. 7117  HOME : HTAB 11: INVERSE : PRINT "KENO INSTRUCTIONS": NORMAL : PRINT 
  226. 7120  PRINT : PRINT "SAVING A GAME:  WHEN YOU SELECT THE QUITOPTION AT THE END OF THE BETTING        SEQUENCE YOU MAY ELECT TO SAVE THE      STATUS OF THAT GAME ON DISK FOR FUTURE  RECALL.  YOU MAY SAVE UP TO 10 DIFFERENT";
  227. 7130  PRINT "EACH IDENTIFIED BY A NUMBER (0-9).": PRINT : PRINT "NOTE: TRYING TO RECALL A GAME THAT HAS  NOT BEEN SAVED WILL RESULT IN A;        *FILE NOT FOUND* ERROR.  IN WHICH CASE, JUST TYPE 'RUN' TO BEGIN PLAY AGAIN."
  228. 7140  VTAB 24: INVERSE : PRINT "   PRESS ANY KEY                    ";: GET A$: PRINT 
  229. 7150  HOME : HTAB 11: INVERSE : PRINT "KENO INSTRUCTIONS": NORMAL : PRINT 
  230. 7160  PRINT "HOUSE PRECENTAGE:  AS SHOWN FOR EACH    PRICE TICKET IS THE ACTUAL % ADVANTAGE  THAT THE HOUSE (CASINO) HAS.
  231. 7170  PRINT : PRINT "TOTAL PERCENT:  AS SHOWN AFTER EACH BET,IS THE % OF WINNINGS VS INITIAL STAKE   YOU HAVE MADE DURING THAT GAME."
  232. 7180  VTAB 24: INVERSE : PRINT "   PRESS ANY KEY                    ";: GET A$: PRINT : NORMAL 
  233. 7500  RETURN 
  234. 7510  REM <CTRL-J><CTRL-J><CTRL-J>
  235. 8000  END 
  236. 9000  REM  QUIT
  237. 9010  HOME : PRINT "SAVE THIS GAME (Y/N) ";: GET A$: PRINT : IF A$ = "Y"  THEN 9030
  238. 9015  HOME : VTAB 12: HTAB 19: PRINT "BYE": END 
  239. 9020  REM <CTRL-J><CTRL-J><CTRL-J><CTRL-J>
  240. 9030  REM  SAVE TOTALS TO DISK
  241. 9035  GOSUB 9200: REM  GET FILE #
  242. 9040 D$ =  CHR$(4)
  243. 9050  PRINT D$;"OPEN KENO DATA FILE ";A$
  244. 9060  PRINT D$;"WRITE KENO DATA FILE ";A$
  245. 9070  PRINT WT: REM  WINNINGS TOTALS
  246. 9080  PRINT BS: REM  BEGINNING STAKE
  247. 9090  PRINT D$;"CLOSE KENO DATA FILE ";A$
  248. 9100  GOTO 9015
  249. 9200  REM  INPUT FILE#
  250. 9210  HOME 
  251. 9220  VTAB 5: HTAB 1: PRINT "WHICH FILE (1-9) ";: GET A$: PRINT 
  252. 9230 FI =  VAL(A$): IF FI <1  OR FI >9  THEN 9220
  253. 9240  RETURN : REM <CTRL-J><CTRL-J><CTRL-J>
  254. 10000  REM  SPOT PAY-OFF DATA
  255. 10010  DATA   3.2: REM   1SPOT
  256. 10020  DATA   0,3.25
  257. 10030  DATA  0,.25,11.75
  258. 10040  DATA  0,.25,1.25,29.5
  259. 10050  DATA  0,0,1.5,13,166
  260. 10060  DATA  0,0,.5,2.8,55,620
  261. 10070  DATA  0,0,0,0,0,0,0
  262. 10080  DATA   0,0,0,.8,7.2,53.9,402.5,1920
  263. 10090  DATA  0,0,0,.15,1.8,17.8,110.7,1000,2250
  264. 10100  DATA  0,0,0,0,.5,4.5,45,325,650,2500 
  265. 10110  DATA  0,0,0,0,.6,5.1,42.3,267,845,1800,5500
  266. 10120  DATA  0,0,0,0,.25,2.25,14.95,85.2,299.25,720.25,1533.25,4000
  267. 10130  DATA  0,0,0,0,.35,2.85,17.7,100.1,360.1,950.3,2035,4110,9540
  268. 10140  DATA  0,0,0,0,.3,2.3,13.4,70.65,253.25,694,1552.4,3060,5900,13000
  269. 10150  DATA  0,0,0,0,.25,1.8,9.8,48.85,172.35,480,1107.45,2225,4130,7700,16000
  270. 10199  REM  <CTRL-J><CTRL-J><CTRL-J>
  271. 10200  REM  TICKET PRICE DATA
  272. 10210  DATA   1.00,2.00,3.00,0.00
  273. 10220  DATA  0.25,0.50,1.00,0.00
  274. 10230  DATA  0.25,0.50,1.00,0.00
  275. 10240  DATA  0.25,0.50,1.00,0.00
  276. 10250  DATA  0.50,1.00,5.00,0.00
  277. 10260  DATA  0.50,1.00,5.00,0 
  278. 10270  DATA   0,0,0,0
  279. 10280  DATA  0.50,1.00,7.00,0
  280. 10290  DATA  0.50,1.00,2.00,4.00
  281. 10300  DATA  0.25,0.50,1.00,2.50
  282. 10310  DATA  0.55,1.10,2.75,0
  283. 10320  DATA  0.40,0.80,2.40,0
  284. 10330  DATA  0.95,2.85,5.70,0
  285. 10340  DATA   1.25,5.00,10.00,0
  286. 10350  DATA   1.50,7.50,15.00,0
  287. 10499  REM <CTRL-J><CTRL-J><CTRL-J>
  288. 10500  REM  PAY-OFF DATA 3
  289. 10510  DATA  1,2,3,0
  290. 10520  DATA  1,2,4,0
  291. 10530  DATA  1,2,4,0
  292. 10540  DATA  1,2,4,0 
  293. 10550  DATA  1,2,10,0
  294. 10560  DATA  1,2,10,0
  295. 10570  DATA  0,0,0,0
  296. 10580  DATA  1,2,14,0
  297. 10590  DATA  1,2,4,8
  298. 10600  DATA  1,2,4,10
  299. 10610  DATA  1,2,5,0
  300. 10620  DATA  1,2,6,0
  301. 10630  DATA  1,3,6,0
  302. 10640  DATA  1,4,8,0
  303. 10650  DATA  1,5,10,0
  304. 10660  REM <CTRL-J><CTRL-J><CTRL-J>
  305. 11000  REM  HOUSE PERCENTAGE DATA
  306. 11010  DATA    20.0,21.8,26.4,24.7,21.5,21.3,00.0,20.2,21.2,20.7,25.6,18.9,20.1,23.1,23.8
  307. 15000  REM    <CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J>BY MIKE SICKBERT            7408 REEDS LN.              OVERLAND PK.,KS                       66204<CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J>